Содержание Назад Вперед

Поверхность с особыми точками

# $Id: singulr.dem%v 3.38.2.97 1993/03/16 15:07:24 woo Exp woo $
#
# Пример построения графиков поверхностей с особенностями.
# Автор: Carsten Steger
#
# (x,y,x ² - y ²,2xy) график w=z ² в 4-х мерном пространстве.
# Следовательно (x ² - y ²,2xy,x,y) график w=sqrt(z).
# Координаты 1, 2, и 3 дают действительную часть функции,
# координаты 1, 2, и 4 дают мнимую часть.
# Аналогично для функции w=z^3. 
# (x,y,x ³ - 3xy ²,3x ² y - y ³) and (x ³ - 3xy ²,3x ² y - y ³,x,y).
# и так далее...


set parametric
set hidden3d
set isosamples 21
set autoscale


set view 60,30
set urange [-3:3]
set vrange [-3:3]
set title "Real part of complex square root function"
splot u**2-v**2,2*u*v,u

set view 60,210
set title "Real part of complex square root function (different view)"
replot

set view 60,120
set urange [-3:3]
set vrange [-3:3]
set title "Imaginary part of complex square root function"
splot u**2-v**2,2*u*v,v

set view 60,300
set title "Imaginary part of complex square root function (different view)"
replot

set view 60,30
set urange [-3:3]
set vrange [-3:3]
set title "Real part of complex cube root function"
splot u**3-3*u*v**2,3*u**2*v-v**3,u

set view 60,210
set title "Real part of complex cube root function (different view)"
replot

set view 60,30
set urange [-3:3]
set vrange [-3:3]
set title "Imaginary part of complex cube root function"
splot u**3-3*u*v**2,3*u**2*v-v**3,v

set view 60,210
set title "Imaginary part of complex cube root function (different view)"
replot

set view 60,30
set isosamples 31
set urange [-1:1]
set vrange [-1:1]
set title "Real part of complex 4th root function"
splot u**4-6*u**2*v**2+v**4,4*u**3*v-4*u*v**3,u

set view 60,210
set title "Real part of complex 4th root function (different view)"
replot

set view 60,120
set urange [-1:1]
set vrange [-1:1]
set title "Imaginary part of complex 4th root function"
splot u**4-6*u**2*v**2+v**4,4*u**3*v-4*u*v**3,v

set view 60,300
set title "Imaginary part of complex 4th root function (different view)"
replot

set isosamples 21
set view 60,20
set urange [-3:3]
set vrange [-3:3]
set title "Enneper's surface"
splot u-u**3/3+u*v**2,v-v**3/3+v*u**2,u**2-v**2

set view 60,110
set title "Enneper's surface (different view)"
replot

set isosamples 31,11
set view 60,30
set title "Moebius strip"
set urange [0:2*pi]
set vrange [-0.25:0.25]
splot (2-v*sin(u/2))*sin(u),(2-v*sin(u/2))*cos(u),v*cos(u/2)

set view 60,210
set title "Moebius strip (view from opposite side)"
replot

set nokey
set xrange [-10:10]
set yrange [-10:10]
set zrange [-3:3]
set urange [0:2*pi]
set vrange [0:2*pi]
set isosamples 39,60
set view 60,120
set title "Klein bottle"
splot  (2*sin(u)*cos(v/2)-sin(2*u)*sin(v/2)+8)*cos(v), \
       (2*sin(u)*cos(v/2)-sin(2*u)*sin(v/2)+8)*sin(v), \
        2*sin(u)*sin(v/2)+sin(2*u)*cos(v/2)

set urange [0:2*pi]
set vrange [0:4*pi/3]
set isosamples 39,40
set view 60,20
set title "Klein bottle with look at the 'inside'"
replot

set data style lines
set xrange [-12:12]
set yrange [-12:12]
set zrange [-1:15]
set nohidden3d
set view 50,15
set title "Klein bottle, glassblowers' version (look-through)"
splot "klein.dat"

set hidden3d
set view 70,305
set title "Klein bottle, glassblowers' version (solid)"
splot "klein.dat"

set autoscale
set title ""
set key
set noparametric
set nohidden3d
set samples 100
set isosamples 10
set view 60,30